﻿#---------------------------------------------------------------------
# Copyright 2001-2009, CrossWire Bible Society (www.crosswire.org)
# All rights reserved.  Usage permitted according to the MIT/X11
# License: http://www.opensource.org/licenses/mit-license.php
#---------------------------------------------------------------------
# Based on SBL Greek transliteration from
# The SBL Handbook of Style p. 29
#---------------------------------------------------------------------
# Greek-Latin/SBL
:: NFD (NFC);
$nasalGamma = [ΓΚΞΧγκξχ];
$diphvowel = [αεηοΑΕΗΟ];
$iota = [Ιι];
$macron = ̄;
# Completeness mappings
|PH<F;
|I<J;
|K<Q;
|Y<V;
|Y<W;
|Y<U;
|ph<f;
|i<j;
|k<q;
|y<v;
|y<w;
|y<u;
# Non-letter characters
ͅ>;
ͺ>;
ʽ>;
·>;
̓>;
ʼ>;
́>;
´>;
ˊ>;
΄>;
͂>;
̂>;
'^'>;
ˆ>;
̀>;
'`'>;
ˋ>;
̈>;
¨>;
# titlecase digraphs
Θ}[:Ll:]<>Th;
Ξ}[:Ll:]<>Ks;
Φ}[:Ll:]<>Ph;
Χ}[:Ll:]<>Kh;
Ψ}[:Ll:]<>Ps;
Ῥ}[:Ll:]<>Rh;
# Uppercase
|$1̔<H([:Lu:]);
|&Any-Upper($1)̔<H([:Ll:]);
|$1̔<h([:L:]);
($diphvowel)Υ>|$1 U;
Υ}$iota>U;
Ῥ<>RH;
([:Lu:])̔}[:Lu:]>H|$1;
([:Lu:])̔>H|&Any-Lower($1);
([:L:])̔>h|$1;
Η<>E $macron;
Θ<>TH;
Φ<>PH;
Χ<>CH;
Ψ<>PS;
# more completeness mappings
|K<C;
''<H;
# monographs
Ω<>O $macron;
Α<>A;
Β<>B;
Γ}$nasalGamma>N;
Γ<>G;
Δ<>D;
Ε<>E;
Ζ<>Z;
Ι<>I;
Κ<>K;
Λ<>L;
Μ<>M;
Ν<>N;
Ξ<>X;
Ο<>O;
Π<>P;
Ρ<>R;
Σ<>S;
Τ<>T;
Υ<>Y;
# Archaic
Ϝ>W;
Ϟ>K;
Ϡ>S;
# Lowercase
($diphvowel)υ>|$1 u;
υ}$iota>u;
ῥ<>rh;
η<>e $macron;
θ<>th;
φ<>ph;
χ<>ch;
ψ<>ps;
# more completeness mappings
|k<c;
''<h;
ω<>o $macron;
α<>a;
β<>b;
γ}$nasalGamma>n;
γ<>g;
δ<>d;
ε<>e;
ζ<>z;
ι<>i;
κ<>k;
λ<>l;
μ<>m;
ν<>n;
ξ<>x;
ο<>o;
π<>p;
ρ<>r;
ς<>s}[:^L:];
σ<>s;
τ<>t;
υ<>y;
# Archaic
ϝ>w;
ϟ>k;
ϡ>s;
:: NFC (NFD);
